How to write a p-adic exponent b^k as a Power series in k ?

edit

To verify the inequality for an even integer $k$, there is no need to use $3$-adic machinery - it's enough to perform calculation over integers modulo $3^4$. We just need to notice that $\gamma_1\equiv -1\pmod{3}$ and thus for even $k$, $$\gamma_1^k = (1 + (-1-\gamma_1))^k \equiv \sum_{i=0}^3 \binom{k}{i} (-1-\gamma_1)^i \pmod{3^4}.$$ Similarly, we have $\gamma_2\equiv 1\pmod{3}$ and $$\gamma_2^k = (1 + (-1+\gamma_2))^k \equiv \sum_{i=0}^3 \binom{k}{i} (-1+\gamma_2)^i \pmod{3^4}.$$ Also, we have $$(\gamma_j^2 - 3)^{-1} = (1+(\gamma_j^2 - 4))^{-1} \equiv \sum_{i=0}^3 \binom{-1}{i} (\gamma_j^2-4)^i \pmod{3^4},\qquad j\in\{1,2\}.$$

Now, a sample code that verifies the inequality:

R.<x> = Zmod(3^4)[]
K.<kk> = ZZ[]
k = 2*kk

g1 = ZZ( next(r for r in (x^2+x+3).roots(multiplicities=False) if r%3==2) )
g2 = ZZ( next(r for r in (x^2+2*x+3).roots(multiplicities=False) if r%3==1) )

ck = K(sum( binomial(k,i) * (-1-g1)^i for i in range(4) ) * sum( binomial(-1,i) * (g1^2-4)^i for i in range(4) ) + \
    sum( binomial(k,i) * (-1+g2)^i for i in range(4) ) * sum( binomial(-1,i) * (g2^2-4)^i for i in range(4) ) + 1)

print( all( (ck - 9*(-1+4*k^2) - 27*(k^3+k^4)).subs({kk:v})==0 for v in Zmod(3^4) ) )