Differential equation for function involving hyperbolic Sine

edit

Are you sure $K(z)$ satisfies a linear ODE? Below I derive an ODE but it's not linear.

Let us first rewrite and simplify $K(z)$: $$K(z) = \frac{\sqrt{z^2+2a}}{2z(2\log(z+\sqrt{z^2+2a})-\log(2a))}.$$ It is important to notice that expressions for $K(z)$ and its derivatives are rational functions in $z$, $u:=\log(2a)-2\log(z+\sqrt{z^2+2a})$ and $v:=\sqrt{z^2+2a}$. We will need to eliminate the latter two. To so, we will compute $K^{(n)}(z)$ for $n=0,1,2$ and turn them into polynomial equations in $z$, $K^{(n)}(z)$, and $u,v$ and then eliminate $u,v$ from these polynomials.

R = PolynomialRing(QQ,6,names='K0,K1,K2,z,u,v')
k = R.gens()[:3]
Z,u,v = R.gens()[3:]

z,a = var('z a')
K = sqrt(z^2+2*a)/(z*(4*log(z+sqrt(z^2+2*a))-2*log(2*a)))

pol = []
for i in (0..2):
    S = str(K.diff(z,i)).replace('log(2*a) - 2*log(z + sqrt(z^2 + 2*a))','u').replace('sqrt(z^2 + 2*a)','v').replace('(z^2 + 2*a)^(3/2)','v^3')
    #print(i,S)
    pol.append( numerator( sage_eval(S,locals={'z':Z,'u':u,'v':v}) - k[i] ) )

p2 = [pol[0].subresultants(e,u)[0] for e in pol[1:]]     # eliminating u
r = p2[0].subresultants(p2[1],v)[0]                          # eliminating v
print( factor(r) )

As a result it prints:

(-1/65536) * v * K0^3 * (4*K0 - 1)^3 * z^17 * (-8*K0*K1^2*z^2 + 4*K0^2*K2*z^2 - 8*K0^2*K1*z - K1^2*z^2 - K0*K2*z^2 - 8*K0^3 - 3*K0*K1*z)^2

Ignoring linear factors (which correspond to extraneous solutions), we get that $K(z)$ satisfies the following ODE: $$-8z^2KK'^2 + 4z^2K^2K'' - 8zK^2K' - z^2K'^2 - z^2KK'' - 8K^3 - 3zKK'=0,$$ which is not linear however.