matrix over symbolic ring to matrix over finite field

edit

In the code you added, the ideal ends up in a univariate polynomial ring over a multivariate polynomial ring, rather than a multivariate polynomial ring with an extra variable.

Here is a version (avoiding the symbolic ring) where the ideal ends up in the correct ring:

mu1, mu2, mu = [1,1],[1,1],[2,2]

def mu_vars(mu):
    svs = [] 
    for i in range(1,2):
        for j in range(i+1,2+1):
            for k in range(0,mu[j-1]):
                svs.append('x_{}_{}_{}'.format(i,j,k+1))
    return svs

svs = mu_vars(mu) 
R = PolynomialRing(GF(101), ['s'] + svs, order='degrevlex')
s = R.gen(0)

def insert_row(mat,row):
    return matrix(R, mat.rows()[:mat.nrows()]+[row]+mat.rows()[mat.nrows():])

def upper_row_matrix(row):
    symbMat = []
    for i in range(row,2):
        mat = matrix(R, mu[row-1]-1,mu[i])
        v = [v for v in svs if v.startswith('x_{}_{}'.format(row,i+1))]
        d = insert_row(mat,v)
        symbMat.append(d)
    return symbMat

def mu_matrix(mu1,mu2):
    x = polygen(R)
    symbMat = []
    for i in range(0,2):
        row = [] + [0]*i
        p = x**(mu1[i])*(x-s)**(mu2[i])
        row.append(companion_matrix(p.coefficients(sparse=False),format='bottom'))
        row += upper_row_matrix(i+1)
        symbMat.append(row)
    return block_matrix(R,symbMat)

m = mu_matrix(mu1,mu2)

R.ideal(m.minors(2)[29]).groebner_basis()

You may want to adapt the monomial ordering.

A good rule of thumb is that it is better to be explicit than implicit: when defining matrices and ideals, specify the ring that they are to be defined over. And avoid the symbolic ring when possible.

(The above could also be adapted so that the extra variable s is not in R but in a second polynomial ring.)

The problem is that, fundamentally, a symbolic expression is a tree whose leaf nodes are variables, whereas a polynomial is a list of (monomial, coefficient) pairs the monomials being themselves lists of (indeterminate, power) pairs; the fact that the notations "^", "+" and "*" are homonyms is (almost) an historical accident. A symbolic expression may have an analytic meaning, a polynomial is strictly algebraic.

There is no built-in way for Sage to construct the list you wish to build from your tree. However, it can be done using the (accidental) common representation... as a character string. The following horror works :

sage: Lv = ("x", "y")
sage: Li = ("u", "v")
sage: var(Lv)
(x, y)
sage: R1=PolynomialRing(GF(101), Li)
sage: P = x^2 - x*y + y^3
sage: S = repr(P)
sage: for r in zip(Lv, Li) : S = S.replace(r[0], r[1])
sage: Q = R1(S)
sage: Q
v^3 + u^2 - u*v
sage: Q.parent()
Multivariate Polynomial Ring in u, v over Finite Field of size 101

but keep in mind that this is a pure typographical manipulation, with no intrinsic mathematical meaning at the level of the symbols used. (This has of course a mathematical meaning in terms of manipulation of strings..., but this is irrelevant to your problem).

HTH,

EDIT : PS : note that you can obtain directly a relevant polynomial by :

sage: Q2 = P.polynomial(base_ring=GF(101))
sage: Q2
y^3 + x^2 - x*y
sage: Q2.parent()
Multivariate Polynomial Ring in x, y over Finite Field of size 101

but the notations are becoming extremely confusing, since :

sage: x.parent()
Symbolic Ring

As far as I know, Sage has no built-in way to substitute an indeterminate for another in a multivariate polynomial, so working (temporarily) in PolynomialRing(GF(101), ["x", "y", "u", "v"]) is a dead end.

Of course, if you don't have to denote the individual indeterminates and work on them at the individual level, you can get away with working only with polynomials :

sage: P
y^3 + x^2 - x*y
sage: T1 = P.polynomial(base_ring=GF(101))
sage: T2 = (x^3-y^2).polynomial(base_ring=GF(101))
sage: T1+T2
x^3 + y^3 + x^2 - x*y - y^2
sage: (T1+T2).parent()
Multivariate Polynomial Ring in x, y over Finite Field of size 101

Again, you might confuse your readers with such pranks.

EDIT : clarified the definition of a polynomial.