How to find all the sub-square matrices of an 4x4 matrix and all their determinants

asked 2018-02-15 20:24:16 +0100

Redbook1
17 ●3 ●3 ●6

I need to find all the sub-square matrices of a $4 \times 4$ matrix.
Then find the determinant of all $70$ of them.

I was directed to Sage but I know little about it. A simple program would be much appreciated.

For example, the matrix below:

$$2\quad 3\quad 1\quad 1$$ $$1\quad 2\quad 3\quad 1$$ $$1\quad 1\quad 2\quad 3$$ $$3\quad 1\quad 1\quad 2$$

Thanks to anyone who can help.

edit retag flag offensive close merge delete

Comments

Note: if you already figured out how to input a matrix, you would save potential answerers some time by putting that code in your question, ready to copy-paste.

slelievre ( 2018-02-16 00:05:03 +0100 )edit

add a comment

3 Answers

Sort by » oldest newest most voted

answered 2018-02-16 00:45:31 +0100

dan_fulea
5537 ●5 ●43 ●95

updated 2018-02-16 00:46:36 +0100

A possible solution illustrating slicing for submatrices of a given matrix is as follows:

A = matrix( ZZ, 4, 4, [ 2,3,1,1, 1,2,3,1, 1,1,2,3, 3,1,1,2 ] )
print "The matrix A is:\n%s" % A

parts = sorted( [ tuple(S) for S in Set( [0,1,2,3] ).subsets() if S ]
                , key=lambda S: (len(S), S) )
for S in parts:
    for T in parts:
        if len(S) != len(T):
            continue
        print ( "A[ %s , %s ].det() = %s"
                % ( S, T, A.matrix_from_rows_and_columns(S, T).det() ) )

The results are:

The matrix A is:
[2 3 1 1]
[1 2 3 1]
[1 1 2 3]
[3 1 1 2]
A[ (0,) , (0,) ].det() = 2
A[ (0,) , (1,) ].det() = 3
A[ (0,) , (2,) ].det() = 1
A[ (0,) , (3,) ].det() = 1
A[ (1,) , (0,) ].det() = 1
A[ (1,) , (1,) ].det() = 2
A[ (1,) , (2,) ].det() = 3
A[ (1,) , (3,) ].det() = 1
A[ (2,) , (0,) ].det() = 1
A[ (2,) , (1,) ].det() = 1
A[ (2,) , (2,) ].det() = 2
A[ (2,) , (3,) ].det() = 3
A[ (3,) , (0,) ].det() = 3
A[ (3,) , (1,) ].det() = 1
A[ (3,) , (2,) ].det() = 1
A[ (3,) , (3,) ].det() = 2
A[ (0, 1) , (0, 1) ].det() = 1
A[ (0, 1) , (0, 2) ].det() = 5
A[ (0, 1) , (0, 3) ].det() = 1
A[ (0, 1) , (1, 2) ].det() = 7
A[ (0, 1) , (1, 3) ].det() = 1
A[ (0, 1) , (2, 3) ].det() = -2
A[ (0, 2) , (0, 1) ].det() = -1
A[ (0, 2) , (0, 2) ].det() = 3
A[ (0, 2) , (0, 3) ].det() = 5
A[ (0, 2) , (1, 2) ].det() = 5
A[ (0, 2) , (1, 3) ].det() = 8
A[ (0, 2) , (2, 3) ].det() = 1
A[ (0, 3) , (0, 1) ].det() = -7
A[ (0, 3) , (0, 2) ].det() = -1
A[ (0, 3) , (0, 3) ].det() = 1
A[ (0, 3) , (1, 2) ].det() = 2
A[ (0, 3) , (1, 3) ].det() = 5
A[ (0, 3) , (2, 3) ].det() = 1
A[ (1, 2) , (0, 1) ].det() = -1
A[ (1, 2) , (0, 2) ].det() = -1
A[ (1, 2) , (0, 3) ].det() = 2
A[ (1, 2) , (1, 2) ].det() = 1
A[ (1, 2) , (1, 3) ].det() = 5
A[ (1, 2) , (2, 3) ].det() = 7
A[ (1, 3) , (0, 1) ].det() = -5
A[ (1, 3) , (0, 2) ].det() = -8
A[ (1, 3) , (0, 3) ].det() = -1
A[ (1, 3) , (1, 2) ].det() = -1
A[ (1, 3) , (1, 3) ].det() = 3
A[ (1, 3) , (2, 3) ].det() = 5
A[ (2, 3) , (0, 1) ].det() = -2
A[ (2, 3) , (0, 2) ].det() = -5
A[ (2, 3) , (0, 3) ].det() = -7
A[ (2, 3) , (1, 2) ].det() = -1
A[ (2, 3) , (1, 3) ].det() = -1
A[ (2, 3) , (2, 3) ].det() = 1
A[ (0, 1, 2) , (0, 1, 2) ].det() = 4
A[ (0, 1, 2) , (0, 1, 3) ].det() = 3
A[ (0, 1, 2) , (0, 2, 3) ].det() = 11
A[ (0, 1, 2) , (1, 2, 3) ].det() = 17
A[ (0, 1, 3) , (0, 1, 2) ].det() = 17
A[ (0, 1, 3) , (0, 1, 3) ].det() = 4
A[ (0, 1, 3) , (0, 2, 3) ].det() = 3
A[ (0, 1, 3) , (1, 2, 3) ].det() = 11
A[ (0, 2, 3) , (0, 1, 2) ].det() = 11
A[ (0, 2, 3) , (0, 1, 3) ].det() = 17
A[ (0, 2, 3) , (0, 2, 3) ].det() = 4
A[ (0, 2, 3) , (1, 2, 3) ].det() = 3
A[ (1, 2, 3) , (0, 1, 2) ].det() = 3
A[ (1, 2, 3) , (0, 1, 3) ].det() = 11
A[ (1, 2, 3) , (0, 2, 3) ].det() = 17
A[ (1, 2, 3) , (1, 2, 3) ].det() = 4
A[ (0, 1, 2, 3) , (0, 1, 2, 3) ].det() = -35

And we can copy+paste from each of the above lines the determinant computation to convince ourselves that the corresponding relation is true, for instance:

sage: A[ (0, 1, 3) , (0, 1, 2) ].det()
17

where the submatrix is...

sage: A[ (0, 1, 3) , (0, 1, 2) ]
[2 3 1]
[1 2 3]
[3 1 1]

edit flag offensive delete link

Comments

Perfect! Many thanks.

Redbook1 ( 2018-02-16 05:37:57 +0100 )edit

add a comment

answered 2018-02-16 02:02:44 +0100

tmonteil
27423 ●31 ●204 ●517 http://wiki.sagemath.o...

To complement previous answers in a "don't reinvent the wheel" way, let me point to the following two methods:

matrix_from_rows_and_columns if you want to extract submatrices, see this documentation page
minors if you are only interesed in the determinants (you will have to iterate over all sizes), see this documentation page

edit flag offensive delete link

add a comment

answered 2018-02-16 00:22:05 +0100

slelievre
17704 ●22 ●160 ●350 http://carva.org/samue...

To get a square sub-matrix from a square matrix, you just need to delete an equal number of rows and columns.

Define the matrix. For example (starting from a copy-paste of the entries of the matrix...):

sage: m = matrix(ZZ, 4, [ZZ(a) for a in '2311123111233112'])
sage: m
[2 3 1 1]
[1 2 3 1]
[1 1 2 3]
[3 1 1 2]

Explore the available methods using dot and the tab key:

sage: m.<TAB>

Notice the methods delete_rows and delete_columns.

Read their documentation:

sage: m.delete_rows?
sage: m.delete_columns?

To enumerate subsets of size 2 of a set S, we can use Subsets(S, k=2).

Combining all this, write a loop to iterate over all possible numbers of rows and columns to delete.

sage: r = range(4)
sage: for k in [0 .. 4]:
....:     for i in Subsets(r, k=k):
....:         for j in Subsets(r, k=k):
....:             a = m.delete_rows(i).delete_columns(j)
....:             print a
....:             print det(a)
....:

edit flag offensive delete link

Comments

Thank you!

Redbook1 ( 2018-02-16 05:38:19 +0100 )edit

add a comment

Your Answer

Please start posting anonymously - your entry will be published after you log in or create a new account.

Add Answer

How to find all the sub-square matrices of an 4x4 matrix and all their determinants

Comments

3 Answers

Comments

Comments

Your Answer

Question Tools

Stats

Related questions

How to find all the sub-square matrices of an 4x4 matrix and all their determinants edit

Comments

3 Answers

Comments

Comments

Your Answer

Question Tools

Stats

Related questions

How to find all the sub-square matrices of an 4x4 matrix and all their determinants