1 | initial version |

No, you can!

The posted question comes with no special situation, so i will try to generate one with a non-obvious homomorphism of base ring(s). The rings will be `R`

and `S`

, we define some morphism `f`

between them, then the line `Lf = LR.Hom(LS)(f)`

is the answer to the question, it constructs the induced morphism between the Laurent polynomial rings

`LR`

of`R`

, and respectively`LS`

of`S`

.

(There is some issue with the right names for the generators.)

Details in a concrete situation. So let us declare in sage $$R=\mathbb Z[x] / (\ x^2 + 6x + 3 \ )\longrightarrow\mathbb F_{49}=S\ ,$$ as follows:

```
R0.<x> = PolynomialRing(ZZ)
R.<a> = R0.quotient( x^2 + 6*x + 3 )
S.<b> = GF( 7**2, modulus = x^2 + 6*x + 3 )
f = R.Hom(S)( [ b^7, ] )
```

Here, the generator $a$ of $R$ goes to $b^7$. For instance:

```
sage: f( 1+a )
6*b + 2
sage: 1+b^7
6*b + 2
```

We then introduce the Laurent polynomial rings `LR`

, `LS`

over $R,S$, and we have the induced morphism `Lf`

.
Sample code:

```
sage: LR.<s,t> = LaurentPolynomialRing( R )
sage: LS.<s,t> = LaurentPolynomialRing( S )
sage: sR,tR = LR.gens()
sage: Lf = LR.Hom(LS)(f)
sage: Lf
Ring morphism:
From: Multivariate Laurent Polynomial Ring in s, t
over Univariate Quotient Polynomial Ring in a
over Integer Ring with modulus x^2 + 6*x + 3
To: Multivariate Laurent Polynomial Ring in s, t
over Finite Field in b of size 7^2
Defn: Induced from base ring by
Ring morphism:
From: Univariate Quotient Polynomial Ring in a
over Integer Ring with modulus x^2 + 6*x + 3
To: Finite Field in b of size 7^2
Defn: a |--> 6*b + 1
sage: Lf( (1+a)*sR + 8*tR )
(6*b + 2)*s + t
```

The information on `Lf`

was manually arranged.

Note: In such cases please always give the concrete mathematical example of interest. (And of course, code initializing the objects in sage is welcome!) Things become simpler if the

Copyright Sage, 2010. Some rights reserved under creative commons license. Content on this site is licensed under a Creative Commons Attribution Share Alike 3.0 license.