Given that z is a complex number of the form z=a+bi, where a,b∈R, and ¯z is its conjugate, what is limz→0(¯z)2z2=?
When I ask Sage to do this limit, it says it's 1. I am almost certain that's not right. Here's the Sage code:
`sage: z=var('z')
sage: assume(z,'complex')
sage: limit((conjugate(z))^2/z^2,z=0) `
My analysis leads to DNE, so I wonder if I am misusing Sage.
The limit is equivalent to two limits of functions of two real variables
x,y=var('x y',domain=RR)
z=x+I*y
f=(z.conjugate()/z)^2
f, f.rectform()
((x - I*y)^2/(x + I*y)^2,
-4*I*(x^2 - y^2)*x*y/(x^2 + y^2)^2 - (4*x^2*y^2 - (x^2 - y^2)^2)/(x^2 + y^2)^2)It does not exist, since the limits on some subsets are different
limit(f.subs(y=0),x=0), limit(f.subs(x=y),y=0)
(1, -1)Use
plot3d(real_part(f),(x,-1,1),(y,-1,1))
plot3d(imag_part(f),(x,-1,1),(y,-1,1))for better understanding
Using another approach, if a is the modulus and b the argument, then
a,b=var('a b',domain=RR)
z=a*exp(I*b)
f=(z.conjugate()/z)^2;f
e^(-4*I*b)and the limit
limit(f,a=0)
e^(-4*I*b)depends on the argument , so the limit with z->0 does not exist
Thank you! A link to your answer will be shared with my pre-calculus students. YouTube video link: https://youtu.be/9OlsUum8d0g
Another way to see it is to search the directional limit of f :
sage: var("rho, theta", domain="real")
(rho, theta)
sage: f=rho*(cos(theta)+I*sin(theta))
sage: (f.conjugate()^2/f^2).limit(rho=0)._sympy_().simplify().rewrite("sin")._sage_()
cos(4*theta) - I*sin(4*theta)which show that this limit depends of the direction of your trajectory to 0...
BTW :
sage: (f.conjugate()^2/f^2)._sympy_().simplify().rewrite("sin")._sage_()
cos(4*theta) - I*sin(4*theta)which does not depend on rho...
Asked: 2 years ago
Seen: 310 times
Last updated: Dec 03 '22
Copyright Sage, 2010. Some rights reserved under creative commons license. Content on this site is licensed under a Creative Commons Attribution Share Alike 3.0 license.
