Ask Your Question
1

How to solve this equation with double square root?

asked 2017-12-30 19:00:00 -0500

ablmf gravatar image

I am trying to solve this equation in sage $$ \sqrt{-4 \, z^{2} + 2 \, \sqrt{-4 \, z^{2} + 1} - 1} = 0. $$ But when I try the code

var('z')
eq = sqrt(-4*z^2 + 2*sqrt(-4*z^2 + 1) - 1) == 0
solve(eq,z)

I get

[z == -1/2*sqrt(2*sqrt(-4*z^2 + 1) - 1), z == 1/2*sqrt(2*sqrt(-4*z^2 + 1) - 1)]

Is there any way to actually solve it in sage?

edit retag flag offensive close merge delete

Comments

To better specify the question, do you want to solve for $z$ in $\mathbb{Z}$, $\mathbb{Q}$, $\mathbb{R}$, $\mathbb{C}$, other?

slelievre gravatar imageslelievre ( 2017-12-30 19:04:55 -0500 )edit

One thing to notice is that $\sqrt{\operatorname{expression}} = 0$ is equivalent to $\operatorname{expression} = 0$. This gets you rid of one of the square roots.

slelievre gravatar imageslelievre ( 2017-12-30 19:05:41 -0500 )edit

This has two solutions in $\mathbb C$, $\pm \sqrt{2\sqrt{3}-3}/2$.

ablmf gravatar imageablmf ( 2017-12-30 19:12:49 -0500 )edit

If an answer solves your question, please accept it by clicking the "accept" button (the one with a check mark, below the upvote button, score, and downvote button, at the top left of the answer).

This will mark the question as solved in the list of questions on the main page of Ask Sage, as well as in lists of questions related to a particular query.

slelievre gravatar imageslelievre ( 2017-12-31 09:58:45 -0500 )edit

1 answer

Sort by ยป oldest newest most voted
2

answered 2017-12-30 19:19:55 -0500

slelievre gravatar image

updated 2017-12-30 19:39:31 -0500

To better specify the question, one would need to say if we want to solve for $z$ in $\mathbb{Z}$, $\mathbb{Q}$, $\mathbb{R}$, $\mathbb{C}$, or other.

Here we examine how to solve over $\mathbb{C}$.

Define $z$ as a symbolic variable, and define the equation (as you did).

sage: z = SR.var('z')
sage: eq_a = sqrt(-4*z^2 + 2*sqrt(-4*z^2 + 1) - 1) == 0

sage: solve(eq_a, z)
[z == -1/2*sqrt(2*sqrt(-4*z^2 + 1) - 1), z == 1/2*sqrt(2*sqrt(-4*z^2 + 1) - 1)]

First notice that $\sqrt{\operatorname{expression}} = 0$ is equivalent to $\operatorname{expression} = 0$. This gets you rid of one of the square roots.

sage: eq_b = eq_a^2
sage: eq_b
-4*z^2 + 2*sqrt(-4*z^2 + 1) - 1 == 0

Then isolate the other square root.

sage: eq_c = eq_b + 4*z^2 + 1
sage: eq_c
2*sqrt(-4*z^2 + 1) == 4*z^2 + 1

Remove it by squaring. Note that the new equation is implied by the initial one, but no longer equivalent to it.

sage: eq_d = eq_c^2
sage: eq_d
-16*z^2 + 4 == (4*z^2 + 1)^2

Solve the new equation.

sage: sols_d = solve(eq_d, z)
sage: sols_d
[z == -1/2*sqrt(2*sqrt(3) - 3), z == 1/2*sqrt(2*sqrt(3) - 3), z == -1/2*sqrt(-2*sqrt(3) - 3), z == 1/2*sqrt(-2*sqrt(3) - 3)]

Check which of the solutions are solutions of the initial equation.

sage: [bool(eq_a.subs(s)) for s in sols_d]
[True, True, False, False]

Define the solutions of the original equation:

sage: sols_a = [s for s in sols_d if bool(eq_a.subs(s))]
sage: sols_a
[z == -1/2*sqrt(2*sqrt(3) - 3), z == 1/2*sqrt(2*sqrt(3) - 3)]
edit flag offensive delete link more

Your Answer

Please start posting anonymously - your entry will be published after you log in or create a new account.

Add Answer

Question Tools

Stats

Asked: 2017-12-30 19:00:00 -0500

Seen: 177 times

Last updated: Dec 30 '17