Ask Your Question

# Explicit representation of element of ideal

P.<x,y,z,t>=PolynomialRing(QQ,4)
C1= 17*x^2 + 7*y^2 - 26*y*z + 7*z^2
C2= 13*y^2 - 7*y*z + 13*z^2 - 51*t^2
x^4+y^4+z^4-18*t^4 in ideal(C1,C2)


So there exist \alpha, \beta in P with <latex>\alpha C1 + \beta C2 = x^4+y^4+z^4-18*t^4</latex>

What's the command to find \alpha and \beta explicitly ?

edit retag close merge delete

## 1 Answer

Sort by » oldest newest most voted I think you want the .lift() method:

sage: P.<x,y,z,t>=PolynomialRing(QQ,4)
sage: C1= 17*x^2 + 7*y^2 - 26*y*z + 7*z^2
sage: C2= 13*y^2 - 7*y*z + 13*z^2 - 51*t^2
sage: f = x^4+y^4+z^4-18*t^4
sage:
sage: f in ideal(C1,C2)
True
sage:
sage: CI = ideal(C1, C2)
sage: coords = f.lift(CI)
sage: coords
[1/17*x^2 + 1/13*y*z - 21/221*t^2, -7/221*x^2 + 1/13*y^2 + 1/13*z^2 + 6/17*t^2]
sage: rebuilt = sum(coord*base for coord, base in zip(coords, [C1, C2]))
sage: rebuilt
x^4 + y^4 + z^4 - 18*t^4
sage: f == rebuilt
True

more

## Your Answer

Please start posting anonymously - your entry will be published after you log in or create a new account.

Add Answer

## Stats

Asked: 2012-01-17 19:40:59 +0200

Seen: 348 times

Last updated: Jan 17 '12